기본 콘텐츠로 건너뛰기

coffee는 쓰고 싶고 jsx는 쓰기 싫고. 그러면 만들어야지.

이 블로그를 꾸준히 보시는 분들은 아마도 {}, [] 같은 시작과 끝만 알리고 아무것도 실행하지 않는 주제에 오롯이 한 행을 죄다 차지하는게 싫어서 coffee나 jade나 stylus를 쓰는 변태영감탱이의 글들을 읽고 계실거다.

나는 Meteor를 매우 좋아하는 사람이고 Meteor 사용자의 저변을 넓히기 위해 frontend에서 가장 뜨거운 React를 Meteor에서 쓰면 좋다라고 열심히 약을 팔고 있는데.
정작 내게 불편한 것은 jsx였다.

https://facebook.github.io/react/docs/react-without-jsx.html
이런 것이 없는 건 아닌데
이따위로 만들어놨다는 얘기는 쓰지 말란 얘기지.
그리고 어짜피 문서가 아닌데 구태여 코드안에 html을 쓸 이유가 있나?
애초에 html,css,js 로 분리한 건 의미를 가진 문서(html)를 서식화(css)해서 로직(js)을 돌아가게 함인데 이미 html도 css도 쓰지 않는 시점에서 코드안에 html을 섞어쓰는 것은 내겐 매우 불편한 일이었다.

그렇다면 DOM과 같이 위계를 갖는 요소를 어떻게 표현할 것이냐는 의문이 생기는데
다행히도 좋은 모델(http://mithril.js.org/#dom-elements)이 있다.

그러고보니 여기는 기껏 jsx를 지원한다고 했는데 내가 하려고 하는 건 그 반대;; 역시 변태영감인 것이다.
<div>
  <hr>
  <ul>
    <li>
      First
    <li>
      <p style="font-weight: bold">Second</p>
    </li>
  </ul>
  <div>
    <span>110</span>
    <hr>
  </div>
  <div>
    <label for="message">Message</label>
    <input type="text" id="message">
    <button>click</button>
  </div>
  <p>HMM Taste Good!</p>
</div>
요정도를 표현할 수 있으면 좋겠다 싶어서 뽑아보았다.
React는 CSS를 별도로 작성하는 걸 좋아하지 않아보인다. style도 인라인으로 넣었다.
만일 jade(pug) 라면 마치 CSS Selector 처럼.
div
  hr
  ul
    li First
    li
      p(style='font-weight: bold') Second
  div
    span 110
  div
    label(for="message") Message
    input#message(type="text")
    button click
  p HMM Taste Good!
이렇게 만들 수 있을 것이다.
닫는 태그들을 생략하여 라인 수가 줄어들었고 보기에도 편하다.
아마도 내가 원하는 최종 결과물은 다음과 같을 것이다.
b 'div',
  b 'hr'
  b 'ul',
    b 'li', 'First'
    b 'li',
      b 'p', style: 'font-weight': 'bold', 'Second'
  b 'div',
    b 'span', 110
  b 'div',
    b 'label', 'for': 'message', 'Message'
    b 'input', id: 'message', type: 'text'
    b 'button', 'click'
  p 'HMM Taste Good!'
이렇게 하기 위해 React.createElement를 재정의할 필요가 있다.
React.createElement(https://facebook.github.io/react/docs/react-api.html#createelement)는 세개의 인자를 받는데
https://facebook.github.io/react/docs/react-api.html#createelement
React.createElement(
  type,
  [props],
  [...children]
)
type, props, children 세가지다. (props 는 사실 object 인데 왜 []안에 넣어놨는지 모르겠다;;; )
구조상 인자가 null이 들어가는게 아름답지 않고 children이 array면 []를 써야해서 싫다.
편의상 b(mithril은 m)라고 하고 syntactic sugar를 만들어보자.
b = ->
  a = Array.from arguments
  args=[]
  if a.length is 1
    args=[a[0]]
  else
    if a[1]?.$$typeof
      args=[a[0], null, a[1..]]
    else
      if typeof a[1] isnt 'object'
        args=[a[0], null, a[1]]
      else
        args=[a[0], a[1], a[2] and a[2..]]
  React.createElement.apply React, args
결과물은 대략 이렇다. React.createElement의 반환형이 .$$typeof를 가지고 있는 것으로 구분했다.
https://jsbin.com/xaqorac/edit?html,js,output
내 기준으론 만족스럽고 아름답다.

꼭 coffee를 쓰지 않고 js로 해도
b('div',
  b('hr'),
  b('ul',
    b('li', 'First'),
    b('li',
      b('p', {style: {'font-weight': 'bold'}}, 'Second')
    )
  ),
  b('div',
    b('span', 110)
  ),
  b('div',
    b('label', 'for': 'message', 'Message'),
    b('input', id: 'message', type: 'text'),
    b('button', 'click')
  ),
  p('HMM Taste Good!')
)
https://goo.gl/VFvnDU  decaffeinate (http://decaffeinate-project.org/repl/) 로 돌려서 js 변환해보았다.
충분히 아름답다.

* 추가 수정: 반복되는 요소를 표현할 때 map을 쓰는데 반환형이 array인 경우 처리를 포함해야해서 조금 수정했다. 하위 children들은 n개의 arguments로 확장할 수도 있어서 그냥 property가 없는 경우 null을 끼워넣는 식으로 구현하는게 낫겠다 싶어서 수정.
b = ->
  a = Array.from arguments
  args = a
  args.splice 1,0,null if (a[1]?.$$typeof or
    Array.isArray a[1]) or
    (typeof a[1] isnt 'object')
  React.createElement.apply React, args
좀 더 단순하고 유연한 것 같기도.

당연한 얘기지만 React-Native에서도 쓸 수 있다.
Element를 만드는 부분을 분리한다.
React = require 'react'
module.exports = ->
  a = Array.from arguments
  args = a
  args.splice 1,0,null if (a[1]?.$$typeof or
    Array.isArray a[1]) or
    (typeof a[1] isnt 'object')
  React.createElement.apply React, args
그리고 본체에서 사용한다.
React = require 'react'
{
  AppRegistry
  StyleSheet
  Text
  View
} = require 'react-native'
b = require './src/ceact'
class App extends React.Component
  render: ->
    b View, style: styles.container,
      b Text, "Open up main.js to start working on your app."
      b View,
        b Text, key:v, "#{v}number" for v in [1..5]
styles = StyleSheet.create
  container:
    flex: 1
    backgroundColor: '#fff'
    alignItems: 'center'
    justifyContent: 'center'
AppRegistry.registerComponent 'main', => App
coffee로 쓰면 style이 stylus같이 나와서 좋다.
React Native는 각각의 Component를 구성하는 방식이라 "div" 식으로 태그 이름을 쓸 필요가 없다.
사실 React 보다는 React-Native랑 더 어울린다고 본다.
React = require 'react'
{Component} = React
{
  AppRegistry
  StyleSheet
  Text
  View
} = require 'react-native'
b = require './src/ceact'
class App extends Component
  render: ->
    b View, style: styles.container,
      b Text, "Open up main.js to start working on your app."
      b View,
        b Text, key:v, "#{v}number" for v in [1..5]
styles = StyleSheet.create
  container:
    flex: 1
    backgroundColor: '#fff'
    alignItems: 'center'
    justifyContent: 'center'
AppRegistry.registerComponent 'main', => App
잘 작동한다. "" 없이 element를 쓰니 더 좋다.

이 블로그의 인기 게시물

Mac 주의 - 약간 빡치는 git 대소문자 변환 파일명 변환(renaming)하는 법

Mac에서 종종 화나는 일 중 하나가 파일 시스템이 대소문자를 구분하지 않는 점이다.
가령, A.png를 a.png로 바꿔야할 경우 HFS 기준으론 전혀 바뀐 점이 없는 걸로 인식하는데 다소 화가난다.
하지만, 방법이 없는 것은 아닌데

A.png를 임의의 다른 파일로 바꾼다. (ex. A_.png)1에서 바꾼 상태에서 staging 한다. (git add A_.png)1의 파일을 다시 원래 바꾸려고 했던 파일로 바꾼다. (mv A_.png a.png)3을 다시 staging 한다. (git add a.png)commit 한다.https://stackoverflow.com/a/40307511/880991 에서 답변해준 Chris Barr 님에게 감사를.
* 추가

실제로 해보니 git mv --force A.png a.png 가 더 간단하다. 이는 바로 staging 영역에 add까지 해준다.

즐거운 Online Prototyping Tool 들

jsbin, codepen, jsfiddle 이런 것들은 일단 생략. 너무 유명한 것들이라.

https://launchpad.graphql.com - node.js 기반 graphQL 연습장. 이것만으로도 충분히 훌륭한 백엔드
https://codesandbox.io/ npm 사용이 가능한 클라이언트 사이드 연습장. webpackbin이 너무 문제가 많아서 찾아본 것.

https://scrimba.com 이건 codesandbox+ asciinema(https://asciinema.org/) 같은 느낌인데 키 녹화와 음성 녹화 기능이 추가되었다. 다 좋은데 화살표 키로 빨리감기 뒤로감기 기능이 안되고 익스포트(youtube등)으로 지원이 없는게 아쉽다.

이 둘이 만나면? https://codesandbox.io/s/jvlrl98xw3?from-embed
뭐야 이거 무서워 하지마 ㄷㄷ;  graphql+react-native-web(부왘ㅋㅋ)

https://repl.it/languages 전통을 자랑하는 REPL 도구. 지원 언어 종류가 -_-;;;;;

https://tio.run/# repl.it? 장난함? 얘는 지원 언어가 무려 386종류. J랑 아희도 있다.

https://play.golang.org/ 즐거운 go playground. 소스 포멧팅 넘 좋아.

http://decaffeinate-project.org/repl/ 최고의 coffeescript REPL. 원래 용도는 coffee를 ecma6코드로 바꾸는 것이지만...

https://scaphold.io
https://www.graph.cool/ graphql backend service. scaphold.io는 설치도 필요없는 클라우드. graphcool은 호스팅+클라우드 다있음. 둘 다 막상막하. 푸쉬서버도 되고 뭐 미친득.

https://glitch.com/ gomix에서 결국 glitch로 안착.  node.js

https://www.shadertoy.com 잘하고 싶다! 쉐이다! 오디오도 된다!

http:/…

graphql 연습 /w launchpad

https://launchpad.graphql.com/mw9wkzv99
단순 전체쿼리+조건쿼리+추가

http://graphql.org/graphql-js/passing-arguments/
참고. random ID는 crypto 1.0.1 사용
  type Query {
    Members: [member]
    getMember(id: ID!): member
  }
  type member {
    id: ID!
    text: String
  }
  input memberInput {
    text: String
  }
  type Mutation {
    addMember(member: memberInput): member
  } SQL 정의. facebook 쪽은 스트링에 지지는 거 진짜 좋아하네. *.gql 파일이 있다고 하니 이해해주자.
resolver는 var buffer = [];
const resolvers = {
  Query: {
    Members: (root, args, context) => {
      return buffer;
    },
    getMember: (id)=> {
      return buffer.find(o=>o.id)
    }
  },
  Mutation: {
    addMember(_, {member}) {
      const mm = { ...member, id:randomBytes(10).toString('hex') };
      buffer.push(mm);
      return mm;
    }
  }
}; 평범 평범.
https://dev-blog.apollodata.com/tutorial-graphql-subscriptions-server-side-e51c32dc2951 다음으로 pub/sub 연습.
https://launchpad.graphql.com/xvn94n3ql   type Subscription {
    memberAdded: member
  } member가 added되는 순간을 감시. imp…